;;;---------------------------------------------------------
;;;2直線の中心線を構築線で作図後、2点指示でLINE化。
;;; 00/07/12 C9
;;;---------------------------------------------------------

(defun C:CLINE (/ ENT1 ENT2 ENT1P ENT2P P11 P12 P21 P22 PT PT1 PT2 LINE_ANG XP1 DIST
                   CQ_XL ANG LP1 LP2 LPT1 LPT2
                  )
  (C9_IERR)
  (setq ENT1 (entsel "\n 1本目のLINEを選択 または<終了>:"))
  (if ENT1
    (progn
      (setq ENT2 (entsel "\n 2本目のLINEを選択 または<終了>:"))
      (if ENT2
        (progn
          (if (and (eq (C9_DXF 0 (car ENT1)) "LINE")
                   (eq (C9_DXF 0 (car ENT2)) "LINE")
              ) ;_ <<AND
            (progn
              (setq ENT1P (cadr ENT1))
              (setq ENT2P (cadr ENT2))
              (setq P11 (C9_DXF 10 (car ENT1)))
              (setq P12 (C9_DXF 11 (car ENT1)))
              (setq P21 (C9_DXF 10 (car ENT2)))
              (setq P22 (C9_DXF 11 (car ENT2)))
              (if (setq PT (inters P11 P12 P21 P22 NIL))
                (progn (if (< (distance ENT1P P11) (distance ENT1P P12))
                         (setq PT1 P11)
                         (setq PT1 P12)
                       ) ;_ <<IF
                       (if (< (distance ENT2P P21) (distance ENT1P P22))
                         (setq PT2 P21)
                         (setq PT2 P22)
                       ) ;_ <<IF
                       (inters P11 P12 P21 P22 NIL)
                       (C9_MOFF)
                       (command ".XLINE" "B" PT PT1 PT2 "")
                       (C9_MON)
                ) ;_ <<PROGN
                (progn (setq LINE_ANG (angle P11 P12))
                       (setq XP1 (inters P11
                                         (polar P11 LINE_ANG 100)
                                         P21
                                         (polar P21 (+ LINE_ANG (* 0.5 pi)) 100)
                                         NIL
                                 ) ;_ <<inters
                       ) ;_ <<SETQ
                       (setq DIST (/ (distance XP1 P21) 2))
                       (setq PT (polar P21 (angle P21 XP1) DIST))
                       (C9_MOFF)
                       (command ".XLINE" "O" DIST (car ENT2) PT "") ;_ <<command
                       (C9_MON)
                ) ;_ <<PROGN
              ) ;_ <<if
              (setq C9_XL (entlast))
              (setq ANG (angle '(0.0 0.0 0.0) (C9_DXF 11 C9_XL)))
              (if (setq LP1 (getpoint "\n LINEの始点を指定 または<XLINEで終了>:"))
                (if (setq LP2 (getpoint LP1 "\n LINEの終点を指定 または<XLINEで終了>:"))
                  (progn (setq LPT1 (inters PT
                                            (polar PT ANG 100)
                                            LP1
                                            (polar LP1 (+ ANG (* 0.5 pi)) 100)
                                            NIL
                                    ) ;_ <<inters
                         ) ;_ <<setq
                         (setq LPT2 (inters PT
                                            (polar PT ANG 100)
                                            LP2
                                            (polar LP2 (+ ANG (* 0.5 pi)) 100)
                                            NIL
                                    ) ;_ <<inters
                         ) ;_ <<setq
                         (C9_MOFF)
                         (command "LINE" LPT1 LPT2 "")
                         (command "ERASE" C9_XL "")
                         (redraw)
                         (C9_MON)
                  ) ;_ <<PROGN
                ) ;_ <<IF
              ) ;_ <<IF
            ) ;_ <<PROGN
            (prompt "\n LINEｵﾌﾞｼﾞｪｸﾄ限定です。")
          ) ;_ <<IF
        ) ;_ <<PROGN
      ) ;_ <<IF
    ) ;_ <<PROGN
  ) ;_ <<IF
  (C9_REND)
  (princ)
) ;_ <<defun


(defun C9_DXF (CODE ENAME) (cdr (assoc CODE (entget ENAME))))


(defun C9_MOFF ()
  (setq C9_ORTMD (getvar "ORTHOMODE")
        C9_OSMD  (getvar "OSMODE")
        C9_SPMD  (getvar "SNAPMODE")
        C9_CMDEC (getvar "CMDECHO")
  ) ;_ END OF SETQ
  (setvar "ORTHOMODE" 0)
  (setvar "OSMODE" 0)
  (setvar "SNAPMODE" 0)
  (setvar "CMDECHO" 0)
) ;_ <<defun


(defun C9_MON ()
  (setvar "ORTHOMODE" C9_ORTMD)
  (setvar "OSMODE" C9_OSMD)
  (setvar "SNAPMODE" C9_SPMD)
  (setvar "CMDECHO" C9_CMDEC)
) ;_ <<defun


(defun C9_IERR (/ *PRERR*)
  (defun *PRERR* (MSG)
    (princ (strcat "\nerr:" MSG))
    (if C9_ORTMD
      (setvar "cmdecho" C9_ORTMD)
    ) ;_ <<IF
    (if C9_OSMD
      (setvar "osmode" C9_OSMD)
    ) ;_ <<IF
    (if C9_SPMD
      (setvar "orthomode" C9_SPMD)
    ) ;_ <<IF
    (if C9_CMDEC
      (setvar "CMDECHO" C9_CMDEC)
    ) ;_ <<IF
    (if C9_XL
      (entdel C9_XL)
    ) ;_ <<IF
    (setq C9_ORTMD NIL
          C9_OSMD NIL
          C9_SPMD NIL
          C9_CMDEC NIL
    ) ;_ <<SETQ
    (redraw)
    (princ)
  ) ;_ <<defun
  (setq *ERROR* *PRERR*)
) ;_ <<defun

(defun C9_REND ()
  (setq *ERROR* NIL)
  (setq C9_ORTMD NIL
        C9_OSMD NIL
        C9_SPMD NIL
        C9_CMDEC NIL
  ) ;_ <<SETQ
  (princ)
) ;_ <<defun

(prompt "\n コマンド名は CLINE です。")
(princ)